Schönen guten Tag,
der Link zum sqlQuerry existiert nicht mehr? :/
Keine Garantie....bei mir gehts nur noch bis letzten Monat:
DECLARE @Stichtag AS DATE = CONVERT(DATE, '2024.06.30', 102);
SELECT tWarenLagerEingang.kArtikel AS kArtikel,
tArtikel.cArtNr AS Artikelnummer,
tArtikelBeschreibung.cName AS Artikelname,
tWarenLager.cName AS Lager,
CONVERT(FLOAT, SUM(tWarenLagerEingang.fAnzahl) - SUM(ISNULL(Warenausgang.fAnzahl, 0.0))) AS Bestand,
CONVERT(FLOAT, SUM(tWarenLagerEingang.fAnzahl * tArtikel.fEKNetto) - SUM(ISNULL(Warenausgang.fAnzahl, 0.0) * tArtikel.fEKNetto)) AS EKGesamt -- EK aus GLD
--CONVERT(FLOAT, SUM(tWarenLagerEingang.fAnzahl * CASE WHEN tWarenLagerEingang.fEKEinzel > 0.0 THEN tWarenLagerEingang.fEKEinzel ELSE tArtikel.fEKNetto END) - SUM(ISNULL(Warenausgang.fAnzahl, 0.0) * CASE WHEN tWarenLagerEingang.fEKEinzel > 0.0 THEN tWarenLagerEingang.fEKEinzel ELSE tArtikel.fEKNetto END)) AS EKGesamt -- EK aus Wareneingängen
FROM dbo.tWarenLagerEingang
JOIN dbo.tArtikel ON tWarenLagerEingang.kArtikel = tArtikel.kArtikel
JOIN dbo.tSpracheUsed ON nStandard = 1
JOIN dbo.tArtikelBeschreibung ON tArtikel.kArtikel = tArtikelBeschreibung.kArtikel
AND tSpracheUsed.kSprache = tArtikelBeschreibung.kSprache
AND tArtikelBeschreibung.kPlattform = 1
JOIN dbo.tWarenLagerPlatz ON tWarenLagerEingang.kWarenLagerPlatz = tWarenLagerPlatz.kWarenLagerPlatz
JOIN dbo.tWarenLager ON tWarenLagerPlatz.kWarenLager = tWarenLager.kWarenLager
LEFT JOIN
(
SELECT SUM(ISNULL(tWarenLagerAusgang.fAnzahl, 0.0)) AS fAnzahl,
tWarenLagerAusgang.kWarenLagerEingang
FROM dbo.tWarenLagerAusgang
WHERE ISNULL(tWarenLagerAusgang.dErstellt, GETDATE()) < DATEADD(dd, +1, @Stichtag)
GROUP BY tWarenLagerAusgang.kWarenLagerEingang
) AS Warenausgang ON tWarenLagerEingang.kWarenLagerEingang = Warenausgang.kWarenLagerEingang
WHERE tWarenLagerEingang.dErstellt < DATEADD(dd, +1, @Stichtag)
GROUP BY tWarenLagerEingang.kArtikel,
tArtikel.cArtNr,
tArtikelBeschreibung.cName,
tWarenLager.cName
HAVING SUM(tWarenLagerEingang.fAnzahl - ISNULL(Warenausgang.fAnzahl, 0.0)) > 0.0 -- Nur Bestände > 0.0
ORDER BY tArtikel.cArtNr;
GO